.

solutions_only/project 02/ALU.hdl

@@ -0,0 +1,66 @@
+// This file is part of www.nand2tetris.org
+// and the book "The Elements of Computing Systems"
+// by Nisan and Schocken, MIT Press.
+// File name: projects/02/ALU.hdl
+
+/**
+ * The ALU (Arithmetic Logic Unit).
+ * Computes one of the following functions:
+ * x+y, x-y, y-x, 0, 1, -1, x, y, -x, -y, !x, !y,
+ * x+1, y+1, x-1, y-1, x&y, x|y on two 16-bit inputs, 
+ * according to 6 input bits denoted zx,nx,zy,ny,f,no.
+ * In addition, the ALU computes two 1-bit outputs:
+ * if the ALU output == 0, zr is set to 1; otherwise zr is set to 0;
+ * if the ALU output < 0, ng is set to 1; otherwise ng is set to 0.
+ */
+
+// Implementation: the ALU logic manipulates the x and y inputs
+// and operates on the resulting values, as follows:
+// if (zx == 1) set x = 0        // 16-bit constant
+// if (nx == 1) set x = !x       // bitwise not
+// if (zy == 1) set y = 0        // 16-bit constant
+// if (ny == 1) set y = !y       // bitwise not
+// if (f == 1)  set out = x + y  // integer 2's complement addition
+// if (f == 0)  set out = x & y  // bitwise and
+// if (no == 1) set out = !out   // bitwise not
+// if (out == 0) set zr = 1
+// if (out < 0) set ng = 1
+
+CHIP ALU {
+    IN  
+        x[16], y[16],  // 16-bit inputs        
+        zx, // zero the x input?
+        nx, // negate the x input?
+        zy, // zero the y input?
+        ny, // negate the y input?
+        f,  // compute out = x + y (if 1) or x & y (if 0)
+        no; // negate the out output?
+
+    OUT 
+        out[16], // 16-bit output
+        zr, // 1 if (out == 0), 0 otherwise
+        ng; // 1 if (out < 0),  0 otherwise
+
+    PARTS:
+	Mux16(a=x,b[0..15]=false,sel=zx,out=outZx);//zx			+
+	Mux16(a=y,b[0..15]=false,sel=zy,out=outZy);//zy			+
+	
+	Not16(in=outZx,out=outNx1);//nx1
+	Not16(in=outZy,out=outNy1);//ny1
+	Mux16(a=outZx,b=outNx1,sel=nx,out=outNx);//nx			+
+	Mux16(a=outZy,b=outNy1,sel=ny,out=outNy);//ny			+
+	
+	Add16(a=outNx,b=outNy,out=outF1);//f1					+
+	And16(a=outNy,b=outNx,out=outF0);//f0					+
+	Mux16(a=outF0,b=outF1,sel=f,out=outF);//f
+	
+	Not16(in=outF,out=outNo1);//no			+
+	Mux16(a=outF, b=outNo1, sel=no, out=out, out[15]=ng, out[0..7]=zr1, out[8..15]=zr2);	+
+	
+	Or8Way(in=zr1,out=out2);
+	Or8Way(in=zr2,out=out3);
+	Not(in=out2,out=out4);
+	Not(in=out3,out=out5);
+	And(a=out4,b=out5,out=zr);
+	
+}

solutions_only/project 02/Add16.hdl

@@ -0,0 +1,35 @@
+// This file is part of www.nand2tetris.org
+// and the book "The Elements of Computing Systems"
+// by Nisan and Schocken, MIT Press.
+// File name: projects/02/Adder16.hdl
+
+/**
+ * Adds two 16-bit values.
+ * The most significant carry bit is ignored.
+ */
+
+CHIP Add16 {
+    IN a[16], b[16];
+    OUT out[16];
+
+    PARTS:
+   HalfAdder(a=a[0], b=b[0], sum=out[0], carry=carry1);
+   FullAdder(a=a[1], b=b[1], c=carry1, sum=out[1], carry=carry2);
+   FullAdder(a=a[2], b=b[2], c=carry2, sum=out[2], carry=carry3);
+   FullAdder(a=a[3], b=b[3], c=carry3, sum=out[3], carry=carry4);
+   FullAdder(a=a[4], b=b[4], c=carry4, sum=out[4], carry=carry5);
+   FullAdder(a=a[5], b=b[5], c=carry5, sum=out[5], carry=carry6);
+   FullAdder(a=a[6], b=b[6], c=carry6, sum=out[6], carry=carry7);
+   FullAdder(a=a[7], b=b[7], c=carry7, sum=out[7], carry=carry8);
+   FullAdder(a=a[8], b=b[8], c=carry8, sum=out[8], carry=carry9);
+   FullAdder(a=a[9], b=b[9], c=carry9, sum=out[9], carry=carry10);
+   
+   FullAdder(a=a[10],b=b[10],c=carry10,sum=out[10],carry=carry11);
+   FullAdder(a=a[11],b=b[11],c=carry11,sum=out[11],carry=carry12);
+   FullAdder(a=a[12],b=b[12],c=carry12,sum=out[12],carry=carry13);
+   FullAdder(a=a[13],b=b[13],c=carry13,sum=out[13],carry=carry14);
+   FullAdder(a=a[14],b=b[14],c=carry14,sum=out[14],carry=carry15);
+   FullAdder(a=a[15],b=b[15],c=carry15,sum=out[15],carry=carry16);
+
+   
+}

solutions_only/project 02/FullAdder.hdl

@@ -0,0 +1,20 @@
+// This file is part of www.nand2tetris.org
+// and the book "The Elements of Computing Systems"
+// by Nisan and Schocken, MIT Press.
+// File name: projects/02/FullAdder.hdl
+
+/**
+ * Computes the sum of three bits.
+ */
+
+CHIP FullAdder {
+    IN a, b, c;  // 1-bit inputs
+    OUT sum,     // Right bit of a + b + c
+        carry;   // Left bit of a + b + c
+
+    PARTS:
+    HalfAdder(a=b,b=c,sum=sum1,carry=carry1);
+	HalfAdder(a=a,b=sum1,sum=sum,carry=carry2);
+	Or(a=carry1,b=carry2,out=carry);
+	
+}

solutions_only/project 02/HalfAdder.hdl

@@ -0,0 +1,18 @@
+// This file is part of www.nand2tetris.org
+// and the book "The Elements of Computing Systems"
+// by Nisan and Schocken, MIT Press.
+// File name: projects/02/HalfAdder.hdl
+
+/**
+ * Computes the sum of two bits.
+ */
+
+CHIP HalfAdder {
+    IN a, b;    // 1-bit inputs
+    OUT sum,    // Right bit of a + b 
+        carry;  // Left bit of a + b
+
+    PARTS:
+	Xor(a=a,b=b,out=sum);
+	And(a=a,b=b,out=carry);
+}

solutions_only/project 02/Inc16.hdl

@@ -0,0 +1,18 @@
+// This file is part of www.nand2tetris.org
+// and the book "The Elements of Computing Systems"
+// by Nisan and Schocken, MIT Press.
+// File name: projects/02/Inc16.hdl
+
+/**
+ * 16-bit incrementer:
+ * out = in + 1 (arithmetic addition)
+ */
+
+CHIP Inc16 {
+    IN in[16];
+    OUT out[16];
+
+   PARTS:
+	Add16(a=in, b[1..15]=false, b[0]=true , out=out); 
+	
+}